home *** CD-ROM | disk | FTP | other *** search
/ Dr. Windows 3 / dr win3.zip / dr win3 / PROGRAMR / RTX2000.ZIP / rtx2000 / monitor / debugger next >
Text File  |  1992-12-02  |  7KB  |  219 lines
  1. ( ************************** Debugger  ********************************* 
  2.   See main file for description of monitor.
  3.  
  4.   Debugger commands:
  5.      A hex_address                              Alter Memory
  6.      C hex_address_a hex_address_b hex_count    Copy Memory a to Memory b
  7.      D hex_address hex_count                    Dump Memory
  8.      G hex_address                              Go to Address
  9.      S                                          Print stack pointer register
  10.      X                                          Enter Download mode
  11.  
  12.      Download mode accepts a ".ols" file generated by the fc complier when fc
  13.      is invoked with the -o option.  Download mode accepts the ascii/hex file 
  14.      and loads it into memory. Once download mode is entered, the monitor 
  15.      remains in download mode until an escape character is received.  When 
  16.      an escape is received, the monitor will print out a check sum that 
  17.      should be zero after error free download.  
  18.       
  19. )
  20.  
  21. #macro ESC 0x1b
  22. #macro 'A' 0x41
  23. #macro 'C' 0x43
  24. #macro 'D' 0x44
  25. #macro 'G' 0x47
  26. #macro 'S' 0x53
  27. #macro 'X' 0x58
  28. #macro '>' 0x3E
  29. #macro CR 0xD
  30. #macro LF 0xA
  31.  
  32.  
  33. cvariable cmd_index            ( Index of next char in buffer )
  34. cvariable altmode              ( =TRUE for alter memory mode, FALSE otherwise )
  35. variable alt_address          ( Address for alter memory mode )
  36. variable mon_checksum         ( Checksum for download )
  37. cvariable abort_load          ( =TRUE for load abort, FALSE otherwise )
  38. 32 carray cmdbuffer           ( Command buffer )
  39.  
  40.  
  41. : do_prompt ( -- )
  42. ( Print out debugger prompt )
  43.   0 cmd_index c!         ( point to start of command buffer )
  44.   PROMPT emit_string
  45. ;
  46.  
  47. : do_aprompt ( a -- )
  48. ( Prompt for memory alter )
  49.    0 cmd_index c!       ( point to start of command buffer )
  50.    newline              ( carriage return line feed )
  51.    alt_address @ 
  52.    dup .x                 ( Print address )
  53.    @ .x                   ( Print word value )
  54.    '>' emit               ( Print a prompt character )
  55. ; 
  56.  
  57. xlink
  58. : debug_init ( -- )
  59. ( Initialize debugger )
  60.    FALSE altmode c!           ( Normal command mode )
  61.    do_prompt
  62. ;
  63.  
  64. xlink
  65. : debugger ( -- )
  66. ( Waits for, then processes character from test port )
  67.    key
  68.    dup emit                    ( echo char )
  69.    toupper                     ( Force to upper case )
  70.    dup 0x8 = if               ( Check for backspace )
  71.      cmd_index c@ dup if      ( Make sure were not already at start of buffer )
  72.        1 -                    ( do backspace by decrementing index )
  73.      then
  74.    else
  75.      cmd_index c@ over over cmdbuffer + c!   ( save char in buffer )
  76.      1 + 31 and                             ( increment index and mask )
  77.    then
  78.    cmd_index c!                           ( save new cmd_index )
  79.    CR = if
  80.       cmdbuffer skip_space       ( Point to first non space char )
  81.       altmode c@ if
  82.            ram_alter           ( alter memory )
  83.        else
  84.            parse_cmd           ( execute command )
  85.        then
  86.    then
  87. ;
  88.  
  89. : parse_cmd  ( a -- )
  90. ( Parse input command at address a )
  91.      c@+ swap                  ( Get first char, char on top, address next )
  92.      dup 'X' = if
  93.        newline
  94.        downloader             ( download software )
  95.        mon_checksum @ .x
  96.      then
  97.      dup 'A' = if
  98.        swap getnum drop alt_address !    ( Alt function address )
  99.        drop
  100.        TRUE altmode c!                ( Set to alter mode )
  101.        do_aprompt
  102.        exit
  103.      then
  104.      dup 'C' = if
  105.         swap getnum getnum     ( get source and destination addresses )
  106.         >r swap r>             ( source second, destination third )
  107.         getnum drop            ( get count )
  108.         cpy_ram_ram            ( Copy RAM to RAM )
  109.        0 swap                  ( leave two parameters on stack, char on top )
  110.      then
  111.      dup 'D' = if
  112.        swap getnum getnum drop  ( get address and count )
  113.        dumper                   ( do dump )
  114.        0 swap                   ( leave two parameters on stack, char on top )
  115.      then
  116.      dup 'S' = if
  117.         newline
  118.         spr@ .x                     ( print stack pointer register )
  119.      then
  120.      dup 'G' = if
  121.        newline
  122.        >r         ( put char on return stack )
  123.        getnum drop execute    ( Go to )
  124.        0
  125.        r>
  126.      then
  127.      drop                                      ( Drop character )
  128.      drop                                      ( Drop address )
  129.      do_prompt               ( write debugger prompt )
  130. ;
  131.  
  132. : directnum  ( -- n )
  133. ( Get a hex number directly from test port stream, ignore command buffer
  134.   Return 0 if abort_load = TRUE )
  135.    0
  136.    4 for                    ( Always 4 hex digits per number for download )
  137.       begin 
  138.          abort_load c@ if
  139.            TRUE               ( No processing for abort, return 0 )
  140.          else
  141.            key                ( Get a char  )
  142.            dup emit            ( Echo it )
  143.            dup CR = if
  144.              LF emit          ( send line feed for CR )
  145.            then
  146.            dup ESC = if
  147.              TRUE abort_load c!   ( abort load )
  148.            then
  149.            do_digit not
  150.          then
  151.       until                 ( Repeat until valid nibble or abort )
  152.    next
  153.    dup mon_checksum @ +       ( add to checksum )
  154.    rotate_right
  155.    mon_checksum !             ( save checksum )
  156. ;
  157.  
  158. : downloader ( -- )
  159. ( download from PC )
  160.    FALSE abort_load c!    ( load mode )
  161.    0 mon_checksum !       ( clear checksum )
  162.    begin
  163.      directnum drop       ( Configuration )
  164.      directnum            ( Start address )
  165.      directnum            ( Length )
  166.      directnum drop       ( header checksum )
  167.      abort_load c@ if
  168.        drop
  169.      else
  170.        for
  171.          directnum
  172.          swap !+         ( store data into memory if load not aborted )
  173.        next
  174.      then
  175.      drop               ( drop address )
  176.      mon_checksum @
  177.      directnum - mon_checksum !    ( Full checksum )
  178.      abort_load c@
  179.    until
  180. ;
  181.  
  182. : dumper  ( s l -- )
  183. ( Dump starting at s, length l words  )
  184.    0                ( dump count for newlines )
  185.    swap
  186.    for 
  187.       dup 7 and 0= if       ( Print out address every 8 words )
  188.          newline
  189.          over .x               ( print address )
  190.          ": " emit_string      ( print colon )
  191.       then
  192.       swap
  193.         @+             ( Get data using dpr )
  194.       swap .x               ( Print data )
  195.       swap 1 +
  196.    next
  197.    drop
  198.    drop
  199. ;
  200.  
  201. : ram_alter ( a -- )
  202. ( Alter RAM memory, a address of text string )
  203.    dup c@ CR = if
  204.        FALSE altmode c!      ( turn off alter mode )
  205.        drop
  206.        do_prompt
  207.    else
  208.        getnum drop
  209.        alt_address @ !+ alt_address !
  210.        do_aprompt
  211.     then
  212. ;
  213.  
  214.  
  215.  
  216.  
  217.      
  218.     
  219.